Teoría cualitativa local de ecuaciones diferenciales

Conjugación

Vamos a comprobar que los sistemas 
x' = x, y' = -y  
y  
x' = x, y' = -y + x^3 
son topológicamente conjugados.

En primer lugar, vamos a representar las soluciones para ver si son similares

X1[{x_,y_}]={x,-y};X2[{x_,y_}]={x,-y+x^3};

GraphicsGrid[{{StreamPlot[X1[{x,y}],{x,-1,1},{y,-1,1},StreamPoints->Fine],StreamPlot[X2[{x,y}],{x,-1,1},{y,-1,1},StreamPoints->Fine]}},ImageSize->600]

Como podemos ver el comportamiento es similar, que es lo que esperamos cuando son topológicamente conjugados. Vamos a comprobar si h (x, y) = (x, y + x^3/4) es la conjugación.

h[{x_,y_}]={x,y+x^3/4};

D[h[{x,y}],{{x,y}}]

D[h[{x,y}],{{x,y}}].X1[{x,y}]

D[h[{x,y}],{{x,y}}].X1[{x,y}]==X2[h[{x,y}]]

Conjugación a partir de la definición

Veámoslo usando directamente la definición de conjugación.

Para ello, primero queremos crear las ecuaciones. Mathematica no acepta igualdades entre vectores, así que tendremos que crear una pequeña función que nos transforme dos vectores en una lista de igualdades.

Ecuacion[ListaIzquierda_,ListaDerecha_]:=Map[#[[1]]==#[[2]]&,Transpose[{ListaIzquierda,ListaDerecha}]]

Ecuacion[{x'[t],y'[t]},X1[{x[t],y[t]}]]

S1[{x0_,y0_}]:=DSolve[{Ecuacion[{x'[t],y'[t]},X1[{x[t],y[t]}]],x[0]==x0,y[0]==y0},{x[t],y[t]},t]

{x[t],y[t]}/.S1[{x0,y0}][[1]]

S2[{x0_,y0_}]:=DSolve[{Ecuacion[{x'[t],y'[t]},X2[{x[t],y[t]}]],x[0]==x0,y[0]==y0},{x[t],y[t]},t]

Expand[h[{x[t],y[t]}/.S1[{x0,y0}][[1]]]]

Expand[{x[t],y[t]}/.S2[h[{x0,y0}]][[1]]]

Variedad estable e inestable

Vamos a tratar de aproximar la variedad estable e inestable en el origen del siguiente campo

X[{x_,y_}]={-x-y^2,y+x^2}

Dibujamos su campo de pendientes

cp=StreamPlot[X[{x,y}],{x,-1,1},{y,-1,1},StreamPoints->Fine]

Calculamos su parte lineal

A=D[X[{x,y}],{{x,y}}]/.{x->0,y->0}

Dibujamos el campo de pendientes de la parte lineal

cpLineal=StreamPlot[A.{x,y},{x,-1,1},{y,-1,1},StreamPoints->Fine]

Ahora nos quedamos con la parte no lineal

F[{x_,y_}]=X[{x,y}]-A.{x,y}

Y definimos las funciones U y V y la constante a

U[t_]= {{Exp[A[[1,1]]t],0},{0,0}}

V[t_]= {{0,0},{0,Exp[A[[2,2]]t]}}

a={a1,0}

Y definimos el funcional que iteraremos para calcular la variedad estable:

H[u_,t_,a_]:=U[t]. a +Integrate[U[t-s].F[u[s,a]],{s,0,t}] -Integrate[V[t-s].F[u[s,a]],{s,t,Infinity}]

u0[t_,a_]={0,0}

u1[t_,a_]=H[u0,t,a]

u2[t_,a_]=H[u1,t,a]

u3[t_,a_]=H[u2,t,a]

u4[t_,a_]=H[u3,t,a]

u5[t_,a_]=H[u3,t,a]

(Sería muy sencillo definir la función u de forma recursiva, usando n como parámetro, para que nos iterase el número de veces que queremos - queda como ejercicio)

Recordemos que en este caso la variedad estable queda definida por los {a1, a2} tales que a2 es igual a la segunda coordenada de u (t, a). Por tanto, una aproximación será :

Estable5=ContourPlot[a2==u5[0,{a1,0}][[2]],{a1,-1,1},{a2,-1,1},ContourStyle->Black]

Lo dibujamos sobre su campo de pendientes

Show[cp,Estable5]

Variedad central

Vamos a tratar de aproximar la variedad central en el origen del siguiente campo

X[{x_,y_}]={-x^2 y - x^5,-y+x^2}

Representamos el campo

cp=StreamPlot[X[{x,y}],{x,-1,1},{y,-1,1},StreamPoints->Fine]

En este caso, en la parte lineal sólo tenemos la variedad central, x, y la variedad estable, y. Definimos las funciones correspondientes a la parte no lineal.

P=-1;F[{x_,y_}]=X[{x,y}][[1]];G[{x_,y_}]=X[{x,y}][[2]]-P y;

Definimos h1como su serie de Taylor truncada en grado n, dejando sus coeficientes como indeterminadas . Sabemos que la parte lineal de h es cero.

h1[x_,n_]:=Sum[a[i]x^i ,{i,2,n}];

Definimos la condición que hay que imponer (truncada a grado n) :

CondicionCentro[n_]:=Series[D[h1[x,n],x](F[{x,h1[x,n]}])-P h1[x,n]-G[{x,h1[x,n]}],{x,0,n}]

Imponiendo ahora que se verifique la condición, tenemos los coeficientes.

condCentro=Solve[CondicionCentro[4]==0]

Los reemplazamos en h para tener la ecuación de la variedad de centro :

First[h1[x,4]/.condCentro]

Así que la dinámica en la variedad central es : x' = x^4 + O (x^5)

Forma normal

Consideremos el campo
x’=y+ax^2
y’=x^2+exy+x^3

X[{x_,y_}]={y+a x^2,x^2+e x y+x^3}

En este caso, la variedad central es todo el plano. Lo dibujamos con a=1, e=1:

StreamPlot[X[{x,y}]/.{a->1,e->1},{x,-1,1},{y,-1,1},StreamPoints->Fine]

Vamos a calcular su forma normal. Para ello, buscamos una transformación de la forma x=y+h(y). Denotaremos símplemente h(y) a esta transformación. Es más, tomaremos las no-linealidades homogéneas de grado n

h[{x_,y_},n_]:={x,y}+{Sum[a[i,n-i]x^i y^(n-i),{i,0,n}],Sum[b[i,n-i]x^i y^(n-i),{i,0,n}]};

listaCoeficientes[n_]:=Flatten[{Table[a[i,n-i],{i,0,n}],Table[b[i,n-i],{i,0,n}]}]

Mediante el cambio de variable, x=h(y), obtenemos que y’ (truncado a orden n) vale:

Y[{x_,y_},n_]:=Normal[Series[(D[h[{x,y},n],{{x,y}}].X[h[{x ,y},n]])/.{x->t x,y ->t y},{t,0,n}]]/.{t->1}

Por ejemplo, tomando h con no-linealidades homogéneas de grado 2 y truncando en grado dos :

h[{x,y},2]

Expand[Y[{x,y},2]]

Queremos eliminar tantos términos como sea posible. Vamos a generar una lista con todos los términos que es posible anular, igualados a cero.

listaTerminos=Select[Reduce/@(#==0&/@Flatten[CoefficientList[Expand[Y[{x,y},2]],{x,y}]]),Not[AtomQ[#]]&]

Si nos fijamos en los términos a eliminar, nótese que no podemos eliminar a y e simultáneamente (salvo que ambos sean nulos), por tanto debemos elegir. Descartaremos la última ecuación. Elegimos entonces la ecuación con a:

listaTerminos[[-3]]

Si despejamos b[2,0] y sustituimos en h e igualamos a cero el resto de los coeficientes, tenemos:

h[{x,y}]=(First[h[{x,y},2]/.Solve[listaTerminos[[-3]],b[2,0]]])/.(#->0&/@listaCoeficientes[2])

Y el campo (truncando en grado dos) :

Y[{x,y}]=(First[Y[{x,y},2]/.Solve[listaTerminos[[-3]],b[2,0]]])/.(#->0&/@listaCoeficientes[2])

Y[{x,y}]/.{a->1,e->1}

StreamPlot[{y,(x^2)-x y},{x,-1,1},{y,-1,1},StreamPoints->Fine]

Ejercicios

1. ¿Los sistemas x’=x, y’=-y y x’=y, y’=x son conjugados? ¿y los sistemas x’=x, y’=y y x’=y, y’=-x?

2. Obtener una aproximación de la variedad inestable del campo del ejemplo.

Práctica

Consideramos el atractor de Lorenz:

x’=σ(y-x), 
y’=ρ x-y-xz, 
z’=-β z+xy,

con parámetros σ=10, ρ=28 y β=8/3.

1. Calcular los puntos de equilibrio.

2. Determinar la variedad estable e inestable de su linealizado en cada punto de equilibrio.

3. Aproximar la variedad estable en el punto (0,0,0).